Puppet Class: osg::lcmaps_voms

Defined in:
manifests/lcmaps_voms.pp

Summary

Manage lcmaps VOMs

Overview

Parameters:

  • ban_voms (Array) (defaults to: []) —

    VOMs to ban

  • ban_users (Array) (defaults to: []) —

    Users to ban

  • vos (Hash[String, Variant[String, Array, Hash]]) (defaults to: {}) —

    Define osg::lcmaps_voms::vo resources Example: { 'vo' => '/DN' } Example: { 'vo' => { 'dn' => '/DN' } }

  • users (Hash[String, Variant[String, Array, Hash]]) (defaults to: {}) —

    Define osg::lcmaps_voms::user resources Example: { 'user' => '/DN' } Example: { 'user' => { 'dn' => '/DN' } }



16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
 
# File 'manifests/lcmaps_voms.pp', line 16

class osg::lcmaps_voms (
  Array $ban_voms = [],
  Array $ban_users = [],
  Hash[String, Variant[String, Array, Hash]] $vos = {},
  Hash[String, Variant[String, Array, Hash]] $users = {},
) {

  include osg
  include osg::cacerts
  include osg::configure::misc
  contain osg::lcmaps_voms::install
  contain osg::lcmaps_voms::config

  Class['osg']
  -> Class['osg::cacerts']
  -> Class['osg::configure::misc']
  -> Class['osg::lcmaps_voms::install']
  -> Class['osg::lcmaps_voms::config']

  $vos.each |$vo, $dn| {
    if $dn =~ String or $dn =~ Array {
      osg::lcmaps_voms::vo { $vo: dn => $dn }
    } else {
      ensure_resource('osg::lcmaps_voms::vo', $vo, $dn)
    }
  }

  $users.each |$user, $dn| {
    if $dn =~ String or $dn =~ Array {
      osg::lcmaps_voms::user { $user: dn => $dn }
    } else {
      ensure_resource('osg::lcmaps_voms::user', $user, $dn)
    }
  }

}