Puppet Class: osg::gridftp

Defined in:
manifests/gridftp.pp

Summary

Manage OSG GridFTP.

Overview

Parameters:

  • manage_hostcert (Boolean) (defaults to: true) —

    Boolean to set if hostcert should be managed

  • hostcert_source (Optional[String]) (defaults to: undef) —

    Source for hostcert

  • hostkey_source (Optional[String]) (defaults to: undef) —

    Source for hostkey

  • manage_firewall (Boolean) (defaults to: true) —

    Boolean to set if the firewall resources should be managed

  • standalone (Boolean) (defaults to: true) —

    Sets if the GridFTP server is standalone. This parameter is considered private. This parameter is intended for when installing GridFTP on a CE and is handled by osg::ce class



16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
 
# File 'manifests/gridftp.pp', line 16

class osg::gridftp (
  Boolean $manage_hostcert = true,
  Optional[String] $hostcert_source = undef,
  Optional[String] $hostkey_source = undef,
  Boolean $manage_firewall = true,
  Boolean $standalone = true,
) {

  include osg
  include osg::cacerts
  include osg::lcmaps_voms
  include osg::configure::site_info
  contain osg::gridftp::install
  contain osg::gridftp::config
  contain osg::gridftp::service

  if $standalone {
    Class['osg']
    -> Class['osg::cacerts']
    -> Class['osg::gridftp::install']
    -> Class['osg::lcmaps_voms']
    -> Class['osg::configure::site_info']
    -> Class['osg::gridftp::config']
    ~> Class['osg::gridftp::service']
  } else {
    Class['osg::gridftp::install']
    -> Class['osg::lcmaps_voms']
    -> Class['osg::gridftp::config']
    ~> Class['osg::gridftp::service']
  }

  if $manage_firewall {
    firewall { '100 allow GridFTP':
      action => 'accept',
      dport  => '2811',
      proto  => 'tcp',
    }
    firewall { '100 allow GLOBUS_TCP_PORT_RANGE':
      action => 'accept',
      dport  => "${osg::globus_tcp_port_range_min}-${osg::globus_tcp_port_range_max}",
      proto  => 'tcp',
    }

    firewall { '100 allow GLOBUS_TCP_SOURCE_RANGE':
      action => 'accept',
      sport  => "${osg::globus_tcp_source_range_min}-${osg::globus_tcp_source_range_max}",
      proto  => 'tcp',
    }
  }

}