Puppet Class: beegfs

Inherits:
beegfs::params
Defined in:
manifests/init.pp

Summary

Manage BeeGFS

Overview

Examples:

include beegfs

Parameters:

  • client (Boolean) (defaults to: true) —

    Boolean that determines if managing BeeGFS client components

  • mgmtd (Boolean) (defaults to: false) —

    Boolean that determines if managing BeeGFS Mgmtd components

  • meta (Boolean) (defaults to: false) —

    Boolean that determines if managing BeeGFS Meta components

  • storage (Boolean) (defaults to: false) —

    Boolean that determines if managing BeeGFS Storage components

  • admon (Boolean) (defaults to: false) —

    Boolean that determines if managing BeeGFS Admon components

  • utils_only (Boolean) (defaults to: false) —

    Boolean that determines if only BeeGFS utility packages are deployed, ie do not deploy daemons or configs

  • customer_login (Optional[String]) (defaults to: undef) —

    The login to use for commercial access to BeeGFS repos

  • release (String) (defaults to: '7.1') —

    The release of BeeGFS to install

  • version (String) (defaults to: 'present') —

    The version of BeeGFS to install

  • repo_descr (Optional[String]) (defaults to: undef) —

    The BeeGFS repo descr

  • repo_baseurl (Optional[String]) (defaults to: undef) —

    The BeeGFS repo baseurl

  • repo_gpgkey (Optional[String]) (defaults to: undef) —

    The BeeGFS repo gpgkey

  • repo_gpgcheck (Enum['0','1']) (defaults to: '0') —

    The BeeGFS repo gpgcheck

  • repo_enabled (Enum['0','1']) (defaults to: '1') —

    The BeeGFS repo enabled

  • client_package_dependencies (Array) (defaults to: $beegfs::params::client_package_dependencies) —

    The package dependencies for BeeGFS client

  • manage_client_dependencies (Boolean) (defaults to: true) —

    Boolean that sets if BeeGFS client dependencies will be managed

  • mgmtd_host (String) (defaults to: '') —

    The BeeGFS mgmtd host

  • conn_port_shift (Integer) (defaults to: 0) —

    The configuration value for connPortShift

  • client_conn_interfaces (Array) (defaults to: []) —

    The values used to define connInterfacesFile on clients Mutially exclusive with client_conn_interfaces_file

  • client_conn_interfaces_file (Stdlib::Absolutepath) (defaults to: $beegfs::params::conn_interfaces_file['client']) —

    The value for connInterfacesFile on clients Mutially exclusive with client_conn_interfaces

  • mgmtd_conn_interfaces (Array) (defaults to: []) —

    The values used to define connInterfacesFile on mgmtd Mutially exclusive with mgmtd_conn_interfaces_file

  • mgmtd_conn_interfaces_file (Stdlib::Absolutepath) (defaults to: $beegfs::params::conn_interfaces_file['mgmtd']) —

    The value for connInterfacesFile on mgmtd Mutially exclusive with mgmtd_conn_interfaces

  • meta_conn_interfaces (Array) (defaults to: []) —

    The values used to define connInterfacesFile on metadata Mutially exclusive with meta_conn_interfaces_file

  • meta_conn_interfaces_file (Stdlib::Absolutepath) (defaults to: $beegfs::params::conn_interfaces_file['meta']) —

    The value for connInterfacesFile on metadata Mutially exclusive with meta_conn_interfaces

  • storage_conn_interfaces (Array) (defaults to: []) —

    The values used to define connInterfacesFile on storage Mutially exclusive with storage_conn_interfaces_file

  • storage_conn_interfaces_file (Stdlib::Absolutepath) (defaults to: $beegfs::params::conn_interfaces_file['storage']) —

    The value for connInterfacesFile on storage Mutially exclusive with storage_conn_interfaces

  • admon_conn_interfaces (Array) (defaults to: []) —

    The values used to define connInterfacesFile on admon Mutially exclusive with admon_conn_interfaces_file

  • admon_conn_interfaces_file (Stdlib::Absolutepath) (defaults to: $beegfs::params::conn_interfaces_file['admon']) —

    The value for connInterfacesFile on admon Mutially exclusive with admon_conn_interfaces

  • client_conn_net_filters (Array) (defaults to: []) —

    The value used to define connNetFilterFile on clients Mutially exclusive with client_conn_net_filter_file

  • client_conn_net_filter_file (Stdlib::Absolutepath) (defaults to: $beegfs::params::conn_net_filter_file['client']) —

    The value for connNetFilterFile on clients Mutially exclusive with client_conn_net_filter

  • mgmtd_conn_net_filters (Array) (defaults to: []) —

    The value used to define connNetFilterFile on mgmtd Mutially exclusive with mgmtd_conn_net_filter_file

  • mgmtd_conn_net_filter_file (Stdlib::Absolutepath) (defaults to: $beegfs::params::conn_net_filter_file['mgmtd']) —

    The value for connNetFilterFile on mgmtd Mutially exclusive with mgmtd_conn_net_filter

  • meta_conn_net_filters (Array) (defaults to: []) —

    The value used to define connNetFilterFile on metadata Mutially exclusive with meta_conn_net_filter_file

  • meta_conn_net_filter_file (Stdlib::Absolutepath) (defaults to: $beegfs::params::conn_net_filter_file['meta']) —

    The value for connNetFilterFile on metadata Mutially exclusive with meta_conn_net_filter

  • storage_conn_net_filters (Array) (defaults to: []) —

    The value used to define connNetFilterFile on storage Mutially exclusive with storage_conn_net_filter_file

  • storage_conn_net_filter_file (Stdlib::Absolutepath) (defaults to: $beegfs::params::conn_net_filter_file['storage']) —

    The value for connNetFilterFile on storage Mutially exclusive with storage_conn_net_filter

  • admon_conn_net_filters (Array) (defaults to: []) —

    The value used to define connNetFilterFile on admon Mutially exclusive with admon_conn_net_filter_file

  • admon_conn_net_filter_file (Stdlib::Absolutepath) (defaults to: $beegfs::params::conn_net_filter_file['admon']) —

    The value for connNetFilterFile on admon Mutially exclusive with admon_conn_net_filter

  • conn_tcp_only_filters (Array) (defaults to: []) —

    The value used to populate /etc/beegfs/tcp-only-filter

  • conn_tcp_only_filter_file (Stdlib::Absolutepath) (defaults to: $beegfs::params::conn_tcp_only_filter_file) —

    Path to /etc/beegfs/tcp-only-filter

  • ib_package (String) (defaults to: $beegfs::params::ib_package) —

    Package name for libbeegfs-ib

  • with_rdma (Boolean) (defaults to: $beegfs::params::with_rdma) —

    Enable RDMA support with BeeGFS

  • client_mount_path (Stdlib::Absolutepath) (defaults to: '/mnt/beegfs') —

    Path to mount BeeGFS filesystem on client

  • manage_client_mount_path (Boolean) (defaults to: true) —

    Manage the BeeGFS client mount path

  • client_build_args (String) (defaults to: $beegfs::params::client_build_args) —

    Value for client buildArgs

  • client_build_enabled (Boolean) (defaults to: true) —

    Value for client buildEnabled

  • client_config_overrides (Hash) (defaults to: {}) —

    Additional client configurations

  • helperd_config_overrides (Hash) (defaults to: {}) —

    Additional helperd configurations

  • client_package (String) (defaults to: $beegfs::params::client_package) —

    Client package name

  • helperd_package (String) (defaults to: $beegfs::params::helperd_package) —

    Client helperd package name

  • utils_package (String) (defaults to: $beegfs::params::utils_package) —

    Package name for beegfs utils

  • client_manage_service (Boolean) (defaults to: true) —

    Boolean whether to manage client service

  • client_service_name (String) (defaults to: $beegfs::params::client_service_name) —

    Client service name

  • helperd_service_name (String) (defaults to: $beegfs::params::helperd_service_name) —

    Helperd service name

  • client_service_ensure (String) (defaults to: 'running') —

    Client service ensure

  • client_service_enable (Boolean) (defaults to: true) —

    Client service enable

  • client_service_autorestart (Boolean) (defaults to: true) —

    Boolean to set if client will autorestart on changes

  • mgmtd_store_directory (Any) (defaults to: '') —

    The path to mgmtd storage directory

  • mgmtd_config_overrides (Hash) (defaults to: {}) —

    Additional mgmtd configurations

  • mgmtd_package (String) (defaults to: $beegfs::params::mgmtd_package) —

    The BeeGFS mgmtd package

  • mgmtd_manage_service (Boolean) (defaults to: true) —

    Boolean to set if mgmtd service is managed

  • mgmtd_service_name (String) (defaults to: $beegfs::params::mgmtd_service_name) —

    The BeeGFS mgmtd service name

  • mgmtd_service_ensure (String) (defaults to: 'running') —

    The beegfs-mgmtd service ensure

  • mgmtd_service_enable (Boolean) (defaults to: true) —

    The beegfs-mgmtd service enable

  • mgmtd_service_autorestart (Boolean) (defaults to: false) —

    Boolean to set if beegfs-mgmtd will autorestart on changes

  • meta_store_directory (Any) (defaults to: '') —

    The BeeGFS metadata storage directory

  • meta_config_overrides (Hash) (defaults to: {}) —

    Additional metadata configurations

  • meta_package (String) (defaults to: $beegfs::params::meta_package) —

    The BeeGFS metadata package

  • meta_manage_service (Boolean) (defaults to: true) —

    Boolean to set if beegfs-meta service is managed

  • meta_service_name (String) (defaults to: $beegfs::params::meta_service_name) —

    The BeeGFS metadata service name

  • meta_service_ensure (String) (defaults to: 'running') —

    The beegfs-meta service ensure

  • meta_service_enable (Boolean) (defaults to: true) —

    The beegfs-meta service enable

  • meta_service_autorestart (Boolean) (defaults to: false) —

    Boolean to set if beegfs-meta will autorestart on changes

  • storage_store_directory (Any) (defaults to: '') —

    The BeeGFS storage daemon storage directory

  • storage_config_overrides (Hash) (defaults to: {}) —

    Additional storage configurations

  • storage_package (String) (defaults to: $beegfs::params::storage_package) —

    The BeeGFS storage package name

  • storage_manage_service (Boolean) (defaults to: true) —

    Boolean to set if beegfs-storage service is managed

  • storage_service_name (String) (defaults to: $beegfs::params::storage_service_name) —

    The BeeGFS storage service name

  • storage_service_ensure (String) (defaults to: 'running') —

    The beegfs-storage service ensure

  • storage_service_enable (Boolean) (defaults to: true) —

    The beegfs-storage service enable

  • storage_service_autorestart (Boolean) (defaults to: false) —

    Boolean to set if beegfs-storage will autorestart on changes

  • admon_database_file_dir (Stdlib::Absolutepath) (defaults to: '/var/lib/beegfs') —

    The path to BeeGFS admon database directory

  • admon_config_overrides (Hash) (defaults to: {}) —

    Additional BeeGFS Admon configurations

  • admon_package (String) (defaults to: $beegfs::params::admon_package) —

    The BeeGFS Admon package name

  • admon_manage_service (Boolean) (defaults to: true) —

    Boolean to set if beegfs-admon service is managed

  • admon_service_name (String) (defaults to: $beegfs::params::admon_service_name) —

    The BeeGFS Admon service name

  • admon_service_ensure (String) (defaults to: 'running') —

    The beegfs-admon service ensure

  • admon_service_enable (Boolean) (defaults to: true) —

    The beegfs-admon service enable

  • admon_service_autorestart (Boolean) (defaults to: false) —

    Boolean to set if beegfs-admon will autorestart on changes



205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
 
# File 'manifests/init.pp', line 205

class beegfs (
  # which subcomponents should be managed
  Boolean $client     = true,
  Boolean $mgmtd      = false,
  Boolean $meta       = false,
  Boolean $storage    = false,
  Boolean $admon      = false,
  Boolean $utils_only = false,

  Optional[String] $customer_login = undef,

  # packages
  String $release                       = '7.1',
  String $version                       = 'present',
  Optional[String] $repo_descr          = undef,
  Optional[String] $repo_baseurl        = undef,
  Optional[String] $repo_gpgkey         = undef,
  Enum['0','1'] $repo_gpgcheck          = '0',
  Enum['0','1'] $repo_enabled           = '1',
  Array $client_package_dependencies    = $beegfs::params::client_package_dependencies,
  Boolean $manage_client_dependencies   = true,

  # common configuration
  String $mgmtd_host       = '',
  Integer $conn_port_shift  = 0,

  # interfaces
  Array $client_conn_interfaces       = [],
  Stdlib::Absolutepath $client_conn_interfaces_file  = $beegfs::params::conn_interfaces_file['client'],
  Array $mgmtd_conn_interfaces        = [],
  Stdlib::Absolutepath $mgmtd_conn_interfaces_file   = $beegfs::params::conn_interfaces_file['mgmtd'],
  Array $meta_conn_interfaces         = [],
  Stdlib::Absolutepath $meta_conn_interfaces_file    = $beegfs::params::conn_interfaces_file['meta'],
  Array $storage_conn_interfaces      = [],
  Stdlib::Absolutepath $storage_conn_interfaces_file = $beegfs::params::conn_interfaces_file['storage'],
  Array $admon_conn_interfaces        = [],
  Stdlib::Absolutepath $admon_conn_interfaces_file   = $beegfs::params::conn_interfaces_file['admon'],

  # net filters
  Array $client_conn_net_filters      = [],
  Stdlib::Absolutepath $client_conn_net_filter_file  = $beegfs::params::conn_net_filter_file['client'],
  Array $mgmtd_conn_net_filters       = [],
  Stdlib::Absolutepath $mgmtd_conn_net_filter_file   = $beegfs::params::conn_net_filter_file['mgmtd'],
  Array $meta_conn_net_filters        = [],
  Stdlib::Absolutepath $meta_conn_net_filter_file    = $beegfs::params::conn_net_filter_file['meta'],
  Array $storage_conn_net_filters     = [],
  Stdlib::Absolutepath $storage_conn_net_filter_file = $beegfs::params::conn_net_filter_file['storage'],
  Array $admon_conn_net_filters       = [],
  Stdlib::Absolutepath $admon_conn_net_filter_file   = $beegfs::params::conn_net_filter_file['admon'],
  Array $conn_tcp_only_filters        = [],
  Stdlib::Absolutepath $conn_tcp_only_filter_file    = $beegfs::params::conn_tcp_only_filter_file,

  # RDMA specific
  String $ib_package = $beegfs::params::ib_package,
  Boolean $with_rdma = $beegfs::params::with_rdma,

  # client specific - config
  Stdlib::Absolutepath $client_mount_path = '/mnt/beegfs',
  Boolean $manage_client_mount_path = true,
  String $client_build_args = $beegfs::params::client_build_args,
  Boolean $client_build_enabled = true,
  Hash $client_config_overrides = {},
  Hash $helperd_config_overrides   = {},
  # client specific - packages
  String $client_package             = $beegfs::params::client_package,
  String $helperd_package            = $beegfs::params::helperd_package,
  String $utils_package              = $beegfs::params::utils_package,
  # client specific - services
  Boolean $client_manage_service      = true,
  String $client_service_name        = $beegfs::params::client_service_name,
  String $helperd_service_name       = $beegfs::params::helperd_service_name,
  String $client_service_ensure      = 'running',
  Boolean $client_service_enable      = true,
  Boolean $client_service_autorestart = true,

  # mgmtd specific - config
  $mgmtd_store_directory      = '',
  Hash $mgmtd_config_overrides     = {},
  # mgmtd specific - packages
  String $mgmtd_package              = $beegfs::params::mgmtd_package,
  # mgmtd specific - service
  Boolean $mgmtd_manage_service       = true,
  String $mgmtd_service_name         = $beegfs::params::mgmtd_service_name,
  String $mgmtd_service_ensure       = 'running',
  Boolean $mgmtd_service_enable       = true,
  Boolean $mgmtd_service_autorestart  = false,

  # meta specific - config
  $meta_store_directory     = '',
  Hash $meta_config_overrides    = {},
  # meta specific - packages
  String $meta_package             = $beegfs::params::meta_package,
  # meta specific - service
  Boolean $meta_manage_service      = true,
  String $meta_service_name        = $beegfs::params::meta_service_name,
  String $meta_service_ensure      = 'running',
  Boolean $meta_service_enable      = true,
  Boolean $meta_service_autorestart = false,

  # storage specific - config
  $storage_store_directory      = '',
  Hash $storage_config_overrides     = {},
  # storage specific - packages
  String $storage_package              = $beegfs::params::storage_package,
  # storage specific - service
  Boolean $storage_manage_service       = true,
  String $storage_service_name         = $beegfs::params::storage_service_name,
  String $storage_service_ensure       = 'running',
  Boolean $storage_service_enable       = true,
  Boolean $storage_service_autorestart  = false,

  # admon specific - config
  Stdlib::Absolutepath $admon_database_file_dir    = '/var/lib/beegfs',
  Hash $admon_config_overrides     = {},
  # admon specific - packages
  String $admon_package              = $beegfs::params::admon_package,
  # admon specific - service
  Boolean $admon_manage_service       = true,
  String $admon_service_name         = $beegfs::params::admon_service_name,
  String $admon_service_ensure       = 'running',
  Boolean $admon_service_enable       = true,
  Boolean $admon_service_autorestart  = false,
) inherits beegfs::params {

  if ! $release in ['7.1'] {
    fail("${module_name}: Only release 7.1 is supported, ${release} given.")
  }

  if empty($conn_tcp_only_filters) {
    $_conn_tcp_only_filter_file_value   = ''
    $_conn_tcp_only_filter_file_ensure  = 'absent'
  } else {
    $_conn_tcp_only_filter_file_value   = $conn_tcp_only_filter_file
    $_conn_tcp_only_filter_file_ensure  = 'present'
  }

  if $with_rdma {
    $ib_subscribe = Package['libbeegfs-ib']
  } else {
    $ib_subscribe = undef
  }

  ## beegfs-client ##

  if $client or $utils_only {
    if $client_service_autorestart {
      $client_service_subscribe   = delete_undef_values([
        File['/etc/beegfs/beegfs-client.conf'],
        #Augeas['beegfs-client.conf'],
        File['/etc/beegfs/beegfs-mounts.conf'],
        File[$client_conn_interfaces_file],
        File[$client_conn_net_filter_file],
        File[$conn_tcp_only_filter_file],
        File_line['beegfs-client-autobuild buildArgs'],
        File_line['beegfs-client-autobuild buildEnabled'],
        $ib_subscribe,
      ])
      $helperd_service_subscribe  = File['/etc/beegfs/beegfs-helperd.conf']
    } else {
      $client_service_subscribe   = undef
      $helperd_service_subscribe  = undef
    }

    if empty($client_conn_interfaces) {
      $client_conn_interfaces_file_value  = ''
      $client_conn_interfaces_file_ensure = 'absent'
    } else {
      $client_conn_interfaces_file_value  = $client_conn_interfaces_file
      $client_conn_interfaces_file_ensure = 'present'
    }

    if empty($client_conn_net_filters) {
      $client_conn_net_filter_file_value  = ''
      $client_conn_net_filter_file_ensure = 'absent'
    } else {
      $client_conn_net_filter_file_value  = $client_conn_net_filter_file
      $client_conn_net_filter_file_ensure = 'present'
    }

    $helperd_local_configs = {
      'connPortShift'       => $conn_port_shift,
    }

    $client_local_configs = {
      'connPortShift'         => $conn_port_shift,
      'connInterfacesFile'    => $client_conn_interfaces_file_value,
      'connNetFilterFile'     => $client_conn_net_filter_file_value,
      'connTcpOnlyFilterFile' => $_conn_tcp_only_filter_file_value,
      'sysMgmtdHost'          => $mgmtd_host,
    }

    $helperd_default_configs  = merge($beegfs::params::helperd_default_configs[$release], $helperd_local_configs)
    $helperd_configs          = merge($helperd_default_configs, $helperd_config_overrides)
    $helperd_config_keys      = $beegfs::params::helperd_config_keys[$release]

    $client_default_configs = merge($beegfs::params::client_default_configs[$release], $client_local_configs)
    $client_configs         = merge($client_default_configs, $client_config_overrides)
    $client_config_keys     = $beegfs::params::client_config_keys[$release]

    contain beegfs::client
  }

  ## beegfs-mgmtd ##

  if $mgmtd {
    if $mgmtd_service_autorestart {
      $mgmtd_service_subscribe = delete_undef_values([
        File['/etc/beegfs/beegfs-mgmtd.conf'],
        File[$mgmtd_conn_interfaces_file],
        File[$mgmtd_conn_net_filter_file],
        $ib_subscribe,
      ])
    } else {
      $mgmtd_service_subscribe = undef
    }

    if empty($mgmtd_conn_interfaces) {
      $mgmtd_conn_interfaces_file_value   = ''
      $mgmtd_conn_interfaces_file_ensure  = 'absent'
    } else {
      $mgmtd_conn_interfaces_file_value   = $mgmtd_conn_interfaces_file
      $mgmtd_conn_interfaces_file_ensure  = 'present'
    }

    if empty($mgmtd_conn_net_filters) {
      $mgmtd_conn_net_filter_file_value   = ''
      $mgmtd_conn_net_filter_file_ensure  = 'absent'
    } else {
      $mgmtd_conn_net_filter_file_value   = $mgmtd_conn_net_filter_file
      $mgmtd_conn_net_filter_file_ensure  = 'present'
    }

    $mgmtd_local_configs = {
      'connPortShift'       => $conn_port_shift,
      'connInterfacesFile'  => $mgmtd_conn_interfaces_file_value,
      'connNetFilterFile'   => $mgmtd_conn_net_filter_file_value,
      'storeMgmtdDirectory' => $mgmtd_store_directory,
    }

    $mgmtd_default_configs  = merge($beegfs::params::mgmtd_default_configs[$release], $mgmtd_local_configs)
    $mgmtd_configs          = merge($mgmtd_default_configs, $mgmtd_config_overrides)
    $mgmtd_config_keys      = $beegfs::params::mgmtd_config_keys[$release]

    contain beegfs::mgmtd
  }

  ## beegfs-meta ##

  if $meta {
    if $meta_service_autorestart {
      $meta_service_subscribe = delete_undef_values([
        File['/etc/beegfs/beegfs-meta.conf'],
        File[$meta_conn_interfaces_file],
        File[$meta_conn_net_filter_file],
        File[$conn_tcp_only_filter_file],
        $ib_subscribe,
      ])
    } else {
      $meta_service_subscribe = undef
    }

    if empty($meta_conn_interfaces) {
      $meta_conn_interfaces_file_value   = ''
      $meta_conn_interfaces_file_ensure  = 'absent'
    } else {
      $meta_conn_interfaces_file_value   = $meta_conn_interfaces_file
      $meta_conn_interfaces_file_ensure  = 'present'
    }

    if empty($meta_conn_net_filters) {
      $meta_conn_net_filter_file_value   = ''
      $meta_conn_net_filter_file_ensure  = 'absent'
    } else {
      $meta_conn_net_filter_file_value   = $meta_conn_net_filter_file
      $meta_conn_net_filter_file_ensure  = 'present'
    }

    $meta_local_configs = {
      'connPortShift'         => $conn_port_shift,
      'connInterfacesFile'    => $meta_conn_interfaces_file_value,
      'connNetFilterFile'     => $meta_conn_net_filter_file_value,
      'connTcpOnlyFilterFile' => $_conn_tcp_only_filter_file_value,
      'storeMetaDirectory'    => $meta_store_directory,
      'sysMgmtdHost'          => $mgmtd_host,
    }

    $meta_default_configs  = merge($beegfs::params::meta_default_configs[$release], $meta_local_configs)
    $meta_configs          = merge($meta_default_configs, $meta_config_overrides)
    $meta_config_keys      = $beegfs::params::meta_config_keys[$release]

    contain beegfs::meta
  }

  ## beegfs-storage ##

  if $storage {
    if $storage_service_autorestart {
      $storage_service_subscribe = delete_undef_values([
        File['/etc/beegfs/beegfs-storage.conf'],
        File[$storage_conn_interfaces_file],
        File[$storage_conn_net_filter_file],
        File[$conn_tcp_only_filter_file],
        $ib_subscribe
      ])
    } else {
      $storage_service_subscribe = undef
    }

    if empty($storage_conn_interfaces) {
      $storage_conn_interfaces_file_value   = ''
      $storage_conn_interfaces_file_ensure  = 'absent'
    } else {
      $storage_conn_interfaces_file_value   = $storage_conn_interfaces_file
      $storage_conn_interfaces_file_ensure  = 'present'
    }

    if empty($storage_conn_net_filters) {
      $storage_conn_net_filter_file_value   = ''
      $storage_conn_net_filter_file_ensure  = 'absent'
    } else {
      $storage_conn_net_filter_file_value   = $storage_conn_net_filter_file
      $storage_conn_net_filter_file_ensure  = 'present'
    }

    $storage_local_configs = {
      'connPortShift'         => $conn_port_shift,
      'connInterfacesFile'    => $storage_conn_interfaces_file_value,
      'connNetFilterFile'     => $storage_conn_net_filter_file_value,
      'connTcpOnlyFilterFile' => $_conn_tcp_only_filter_file_value,
      'storeStorageDirectory' => $storage_store_directory,
      'sysMgmtdHost'          => $mgmtd_host,
    }

    $storage_default_configs  = merge($beegfs::params::storage_default_configs[$release], $storage_local_configs)
    $storage_configs          = merge($storage_default_configs, $storage_config_overrides)
    $storage_config_keys      = $beegfs::params::storage_config_keys[$release]

    contain beegfs::storage
  }

  ## beegfs-admon ##

  if $admon {
    if $admon_service_autorestart {
      $admon_service_subscribe = [
        File['/etc/beegfs/beegfs-admon.conf'],
        File[$admon_conn_interfaces_file],
        File[$admon_conn_net_filter_file],
        File[$conn_tcp_only_filter_file],
      ]
    } else {
      $admon_service_subscribe = undef
    }

    if empty($admon_conn_interfaces) {
      $admon_conn_interfaces_file_value   = ''
      $admon_conn_interfaces_file_ensure  = 'absent'
    } else {
      $admon_conn_interfaces_file_value   = $admon_conn_interfaces_file
      $admon_conn_interfaces_file_ensure  = 'present'
    }

    if empty($admon_conn_net_filters) {
      $admon_conn_net_filter_file_value   = ''
      $admon_conn_net_filter_file_ensure  = 'absent'
    } else {
      $admon_conn_net_filter_file_value   = $admon_conn_net_filter_file
      $admon_conn_net_filter_file_ensure  = 'present'
    }

    $admon_local_configs = {
      'connPortShift'         => $conn_port_shift,
      'connInterfacesFile'    => $admon_conn_interfaces_file_value,
      'connNetFilterFile'     => $admon_conn_net_filter_file_value,
      'connTcpOnlyFilterFile' => $_conn_tcp_only_filter_file_value,
      'sysMgmtdHost'          => $mgmtd_host,
      'databaseFile'          => "${admon_database_file_dir}/beegfs-admon.db",
    }

    $admon_default_configs  = merge($beegfs::params::admon_default_configs[$release], $admon_local_configs)
    $admon_configs          = merge($admon_default_configs, $admon_config_overrides)
    $admon_config_keys      = $beegfs::params::admon_config_keys[$release]

    contain beegfs::admon
  }

}